# AKT Model
# y(1)  AKT/Xt between 0 and 1 
# y(2)  pIRS/Xt
# time in secs

# Parameters
p  d1ak=0.0909/60
p  k1ak=0.9091/60
p  KK1ak=0.05
p  KK2ak=0.05
p  betaak=1
p  k2ak=0.9091/60
p  deltaak=1/60
p  phiak=1/60(
p  epsak=0.01/60
p  psi=0.559
p  E2T=1
p  lamda=.1
p TSC1=1
p TSC2=1
p TOR=5
p GDP=50
p GTP=50
p k5ak=.01
p k7ak=0.1
p k7bak=0.1
p k6ak=0.1
p k6bak=0.1
p k8ak=8.65
p k8bak=.33
p a1ak=0.21
p d11ak=6.72
p k11ak=0.1
p k9ak=0.01
p k9bak=0.01
p a2ak=0.16
p d2ak=1.86
p k22ak=0.45
p a3ak=0.013
p d3ak=1
p k3ak=2.25
p KTOR=1
p kmtor=300
p Kerk=1
p kneg2=0.1
p kneg3=0.2

# Definitions of concentrations
#y3=TSC1TSC2
#y4=TSC1TSC2pAKT
#y5=R or Rheb
#y6=RGTPTSC1TSC2
#y7=RGTPTOR
#y8=aTOR
#in nanomolar:
p XTak=58
# pAKT=(1-y1)*XT

#ODES

y3'=(k8ak*TSC1*TSC2-k8bak*y3+(d11ak*y4-a1ak*y3*XTak*(1-y1))-kneg2*x14*y3/(Kerk+y3))/60
y4'=(-(d11ak+k11ak)*y4+a1ak*y3*XTak*(1-y1))/60
y5'=(-k6ak*GDP*y5+k6bak*RGDP-k7ak*GTP*y5+k7bak*RGTP)/60
RGTP'=(k7ak*GTP*y5-k7bak*RGTP-k9ak*RGTP+k9bak*RGDP-a2ak*RGTP*y3+d2ak*y6)/60
y6'=(a2ak*RGTP*y3-(d2ak+k22ak)*y6)/60
y7'=(a3ak*RGTP*TOR-(d3ak+k3ak)*y7)/60
y8'=(k3ak*y7-k5ak*y8)/60

#Rtot=0.01
RGDP=0.01-y5-y6-y7-RGTP

#PI3K Model: Steady state is assumed.

p  b1=1
p  b4=1
p  KKb1=100
p  b2=1
p  b3=1
p  KKb2=100
p  KKb3=1
p  P1t=1
p  Pt=100
p  PIPt=100

#y10=aPI3k/Xt
#y2=pIRS/Xt
#y9=PIP3/Xt

y10=(b1/b4)*(Pt/KKb1)*y2/(1+(b1/b4)*(1/KKb1)*y2)
y9=(KKb3/b3)*(b2/KKb2)*(PIPt/P1t)*y10/(1+(KKb3/b3)*(b2/KKb2)*(1/P1t)*y10)

#pIRS and AKT

y1'=(-((d1ak+k1ak)/KK1ak)*y1*(y9-y9*y1/(KK1ak+y1))+d1ak*y1*y9/(KK1ak+y1)+k2ak*E2T*(1-y1)/(KK2ak+(1-y1)))/60
y2'=(lamda+(phiak)*(1-y1)-kmtor*y8*y2/(KTOR+y2)-deltaak*y2)/60



#  MAPK Model
#         z1     EGF_EGFR
#         z2    (EGF_EGFR)2 
#         z3    (EGF_EGFR)2-P
#         z4    (EGF_EGFR)2_PLCg
#         z5    (EGF_EGFR)2_PLCg-P
#         z6    (EGF_EGFR)2_Grb2 
#         z7    (EGF_EGFR)2_Grb2_SOS
#         z8    (EGF_EGFR)2_Shc
#         z9    (EGF_EGFR)2_Shc-P
#         z10   (EGF_EGFR)2_Shc_Grb2
#         z11   (EGF_EGFR)2_Shc_Grb2_Sos
#         z12    Grb2_SOS
#         z13    Shc-P
#         z14    Shc_Grb2
#         z15    PLCg-P
#         z16    PLCg-P-I
#         z17    Shc_Grb2_SOS
#         z18    EGFR
#         z19    EGF
#         z20    PLCg
#         z21    Grb2
#         z22    Shc
#         z23    SOS
#         x(1)  [KKK_E1]
#         x(2)  [KKK*]
#         x(3)  [KKK*_E2]
#         x(4)  [KK_KKK*]
#         x(5)  [KK-P]
#         x(6)  [KK-P_KKP'ase]
#         x(7)  [KK-P_KKK*]
#         x(8)  [KK-PP]
#         x(9)  [KK-PP_KKP'ase]
#         x(10) [K_KK-PP]
#         x(11) [K-P]
#         x(12) [K-P_KP'ase]
#         x(13) [K-P_KK-PP]
#         x(14) [K-PP]
#         x(15) [K-PP_KP'ase]
#         x(16) [KKK]
#         x(17) [KK]
#         x(18) [K]
#         x(19) [E1](RasGTP)
#         x(20) [E2]
#         x(21) [KKP'ase]
#         x(22) [KP'ase]

#Source: Quantification of Short Term Signaling by the Epidermal Growth Factor Receptor[Table 2]
# Parameters p
#Modification: NO - values are same as original ones [No need for conversion of parameters' units]
p kf1=0.003
p kb1=0.06
p kf2=0.01
p kb2=0.1
p kf3=1
p kb3=0.01
p Vu4=450
p Ku4=50
p kf5=0.06
p kb5=0.2
p kf6=1
p kb6=0.05
p kf7=0.3
p kb7=0.006
p Vu8=1
p Ku8=100
p kf9=0.003
p kb9=0.05
p kf10=0.01
p kb10=0.06
p kf11=0.03
p kb11=4.5e-3
p kf12=1.5e-3
p kb12=1e-4
p kf13=0.09
p kb13=0.6
p kf14=6
p kb14=0.06
p kf15=0.3
p kb15=9e-4
p Vu16=1.7
p Ku16=340
p kf17=0.003
p kb17=0.1
p kf18=0.3
p kb18=9e-4
p kf19=0.01
p kb19=2.14e-2
p kf20=0.12
p kb20=2.4e-4
p kf21=0.003
p kb21=0.1
p kf22=0.03;
p kb22=0.064;
p kf23=0.1;
p kb23=0.021;
p kf24=0.009;
p kb24=4.29e-2;
p kf25=1;
p kb25=0.03;

#Source: Digital Signaling and Hysteresis Characterize Ras Activation in Lymphoid Cells.
#Modification: Units changed from micro molar and/or sec to nanomolar and/or sec. "mols"=number of molecules. 
p kfi1=1.125e-4
p kbi1=3
p kfi2=1.0625e-4
p kbi2=0.4
p kcati3=1.75
p kcati4=0.003
p kcati5=0.1
p ki3m=2.7388e3
p ki4m=1.52304e4
p ki5m=1.7869e1

#Source: Bistability and Oscillations in the Huang-Ferrell Model of MAPK Signaling.
p a1=0.00049;
p a2=0.0307;
p a3=0.0204;
p a4=0.0493;
p a5=0.0564;
p a6=0.0326;
p a7=0.0038;
p a8=0.0050;
p a9=0.0056;
p a10=0.0162;
p d1=0.049;
p d2=3.3078;
p d3=10.3862;
p d4=2.7167;
p d5=10.0885;
p d6=0.8134;
p d7=11.5688;
p d8=5.0182;
p d9=8.0892;
p d10=9.7908;
p k1=0.049;
p k2=5.6407;
p k3=7.0000;
p k4=11.1367;
p k5=3.5775;
p k6=1.1328;
p k7=0.7276;
p k8=0.5291;
p k9=1.0955;
p k10=2.9318;

#Negatif Feedback from ERK to SOS.
p k_nfb=0.0; 
p km_nfb=1000; 

#Parameters for TACE
p dT=1;
p gpT=10;
p grT=0;
p KmTACE=1000;
#Parameters for ARGOS
p kAE=5;
p dAE=1;
p dA=0.000001;
p gpA=0.000001;
p KmA=10;
p grAE=0;

#total concentrations
 #EGFR
p tot1=10;
 #EGF
p tot2=0.1;
aux EGFtot=tot2
 #PLCg
p tot3=105;
 #Grb2
p tot4=85;
 #Shc
p tot5=150;
 #SOS
p tot6=50
#Ras#betha
p tot7=200
p Rgap=0.1

#TOTAL concentrations
#Dynamic Modeling and Analysis of the Cross-talk between Insulin/AKT and MAPK/ERK Signaling Pathway Parameters
p tot8=9.2235e-001
p tot9=5.1288e+003
p tot10=8.1552e+002
p tot11=5e-002
p tot12=3.2830e-001
p tot13=2.1238e-001
p tot14=5.0345e+002

#Algebraic Equations for conserved moieties

z18=tot1-(z1+2*(z2+z3+z4+z5+z6+z7+z8+z9+z10+z11))-grAE*AE
z19=tot2+grT*TACE-(z1+2*(z2+z3+z5+z4+z8+z9+z6+z7+z10+z11))
z20=tot3-(z4+z5+z15+z16)
z21=tot4-(z12+z14+z17+z6+z7+z10+z11+SRd+SRt)
z22=tot5-(z13+z14+z17+z8+z9+z10+z11+SRd+SRt)
z23=tot6-(z12+z17+z7+z11+SRd+SRt)
Rd=tot7-(Rt+SRd+SRt+x1)
x16=tot8-(x2+x1+x3+x4+x7)                    
x17=tot9-(x5+x8+x4+x7+x6+x9+x10+x13)
x18=tot10-(x11+x14+x10+x13+x12+x15)              
#x19=tot11-(x1);                                  
x20=tot12-(x3)                                  
x21=tot13-(x6+x9)                               
x22=tot14-(x12+x15)

#Reactions
#Source: Quantification of Short Term Signaling by the Epidermal Growth Factor Receptor(No.49)
r1=kf1*z18*z19-kb1*z1 
r2=kf2*z1*z1-kb2*z2 
r3=kf3*z2-kb3*z3 
r4=Vu4*z3/(Ku4+z3) 
r5=kf5*z3*z20-kb5*z4
r6=kf6*z4-kb6*z5 
r7=kf7*z5-kb7*z3*z15 
r8=Vu8*z15/(Ku8+z15) 
r9=kf9*z3*z21-kb9*z6 
r10=kf10*z6*z23-kb10*z7 
r11=kf11*z7-kb11*z3*z12 
r12=kf12*z12-kb12*z21*z23 
r13=kf13*z3*z22-kb13*z8 
r14=kf14*z8-kb14*z9 
r15=kf15*z9-kb15*z13*z3 
r16=Vu16*z13/(Ku16+z13) 
r17=kf17*z9*z21-kb17*z10 
r18=kf18*z10-kb18*z3*z14 
r19=kf19*z10*z23-kb19*z11 
r20=kf20*z11-kb20*z17*z3 
r21=kf21*z13*z21-kb21*z14 
r22=kf22*z14*z23-kb22*z17 
r23=kf23*z17-kb23*z13*z12 
r24=kf24*z9*z12-kb24*z11 
r25=kf25*z15-kb25*z16 

#ODEs
z1'=r1-2*r2 
z2'=r2+r4-r3 
z3'=r3+r7+r11+r15+r18+r20-r4-r5-r9-r13 
z4'=r5-r6 
z5'=r6-r7 
z6'=r9-r10 
z7'=r10-r11 
z8'=r13-r14 
z9'=r14-r24-r15-r17 
z10'=r17-r18-r19 
z11'=r19-r20+r24 
z12'=r11+r23-r12-r24 
z13'=r15+r23-r21-r16
z14'=r18+r21-r22 
z15'=r7-r8-r25 
z16'=r25 
z17'=-r23+r22+r20-kfi1*z17*Rd+kbi1*SRd-kfi2*z17*Rt+kbi2*SRt-k_nfb*z17*x14/(km_nfb+z17)
SRd'=kfi1*z17*Rd-kbi1*SRd
SRt'=kfi2*z17*Rt-kbi2*SRt
Rt'=-kfi2*z17*Rt+kbi2*SRt+(kcati3*Rd*SRt)/(ki3m+Rd)+(kcati4*Rd*SRd)/(ki4m+Rd)-(kcati5*Rgap*Rt)/(ki5m+Rt)-a1*x16*Rt+(d1+k1)*x1

p Kraf=1

x1'= a1*x16*Rt- (d1+k1)*x1-kneg3*x1*XTak*(1-y1)/(Kraf+x1)
x2'= k1*x1- a2*x2*x20+ d2*x3- a3*x2*x17+(k3+d3)*x4- a5*x5*x2+(k5+d5)*x7
x3'= a2*x2*x20-(d2+k2)*x3
x4'= a3*x17*x2-(d3+k3)*x4
x5'= k3*x4-a4*x5*x21+d4*x6-a5*x5*x2+d5*x7+k6*x9
x6'= a4*x5*x21-(d4+k4)*x6
x7'= a5*x5*x2-(d5+k5)*x7
x8'= k5*x7-a6*x8*x21+d6*x9-a7*x8*x18+(d7+k7)*x10-a9*x11*x8+(d9+k9)*x13
x9'= a6*x8*x21-(d6+k6)*x9
x10'=a7*x18*x8-(d7+k7)*x10
x11'=k7*x10-a8*x11*x22+d8*x12-a9*x11*x8+d9*x13+k10*x15
x12'=a8*x11*x22-(d8+k8)*x12
x13'=a9*x11*x8-(d9+k9)*x13
x14'=k9*x13-a10*x14*x22+d10*x15
x15'=a10*x14*x22-(d10+k10)*x15

#Protease-TACE production by ERK
TACE'=gpT*x14/(KmTACE+x14)-dT*TACE
#ARGOS production
ARGOS'=gpA*x14/(KmA+x14)-dA*ARGOS
#inhibition of EGF by ARGOS. AE:EGF.ARGOS complex
#AE'=kAE*z19*ARGOS-dAE*AE
AE'=kAE*z18*ARGOS-dAE*AE


@ meth=cvode, toler=1e-8, atol=1e-8 
@ bound=600000, yhi=300,ylo=0,xhi=20000,xlo=0,yp=x14,total=20000
 done